Sunrise on Mercury
By: Christina Crow, Emily Tarvin, Kevin Bowman

Abstract

Mercury’s relative proximity to the sun gives it unique properties that make its elliptical orbit more interesting than most planets. Due to the spin-orbit resonance of the planet, there is a unique phenonmenon on Mercury that occurs twice every Mercurian solar day. Using Kepler’s Laws of Planetary Motion, a function of time can be derived to give the area traveled by Mercury along its orbit, then, using the vector from Mercury to the sun and the vector of Mercury’s rotation, the angle for the horizon line from Mercury can be produced. Using this information, it is possible to track the sun from Mercury’s horizon line to demonstrate and better understand the unique occurance at sunrise on Mercury.

Introduction

Mercury orbits in an elliptical path with the sun as a focus. An ellipse is defined as a “curved line forming a closed loop, where the sum of the distances from two points (foci) to every point on the line is constant.” The equation demonstrating this definition is (Subscript[r, 1])+(Subscript[r, 2])=2a, where (Subscript[r, 1])and (Subscript[r, 2]) are the distances from the foci to a point on the curve, and a is the length of the semi-major axis. An ellipse can also be defined as “a conic section formed by the intersection of a right circular cone by a plane that cuts the axis and the surface of the cone.” The equation for this definition is ((x^2)/(a^2))+((y^2)/(b^2))=1. Since we are considering the point at the origin, (Subscript[x, 0]) and (Subscript[y, 0]) are both 0. This equation can be parameterized to find a point on the ellipse for any given angle from the center: x= a cos(ϕ) and y = b sin(ϕ), where a is the length of the semi-major axis and b is the length of the semi-minor axis. 
	The eccentricity of an ellipse is the ratio of the distance from the center of the ellipse to a focus (c) to the length of the semi-major axis (a). The eccentricity of a circle is 0, and the eccentricity of a parabola is 1. Mercury’s orbit has the greatest eccentricity of all the planets in our solar system, with an eccentricity of 0.205. Note that since Mercury’s eccentricity is close to zero, the shape of its orbit is more similiar to a circle than a parabola. 
	The distance measured between Mercury and the sun when Mercury is closest to the sun is called the perihelion, and the distance when Mercury is at its farthest point from the sun is aphelion. The distance of Mercury’s perihelion is 46,001,200 km, and its aphelion measures 69,816,900 km. Mercury’s orbital speed, at an average of 48km/s, is greater than that of any other planet.  At perihelion, its speed is 56.6km/s and at aphelion, its speed is 38.7km/s.  If an airplane could travel this fast, it would take less than 12 minutes for the plane to circle the Earth.  This great speed allows Mercury to orbit the sun in a very short period of time.  One Mercury year, or one complete orbit around the sun, is 88 Earth days. However a solar day, sunrise to sunrise, is 176 Earth days. A sidereal day is the time it takes for a planet to make one rotation with respect to an arbitrary fixed point outside the solar system, such as a star. Mercury’s sidereal day is about 59 Earth days, and is two-thirds of a Mercurian year.  Note a sidereal day on Mercury is shorter than its solar day. It takes Mercury two orbits around the sun to rotate three times, so there is a 3:2 spin:orbit resonance. 
	
The following are important equations to define Mercury’s ellipse:
	a=semi-major axis
b=semi-minor axis
c=distance from center to focus
(Subscript[r, 1])+(Subscript[r, 2])=2a
((x^2)/(a^2))+((y^2)/(b^2))=1
x=a cosϕ, y=b cosϕ
a=((aphelion+perihelion)/2)
c=a-perihelion
b=(Sqrt[(a^2)-(c^2)])=a (Sqrt[1-(eccentricity^2)])
eccentricity=(c/a)=((Sqrt[(a^2)-(b^2)])/a)
Perihelion=46,001,200 km
Aphelion = 69,816,900 km
Area of ellipse= π a b

The diagram below explains the first definition of an ellipse:

With[{a=1,b=.7},With[{c=Sqrt[a^2-b^2]},Graphics[{
Circle[{0,0},{a,b}],
PointSize[.03],Point[{{-c,0},{0,0},{c,0}}],
Line[{{# c,-.1},{# c,-1.}}]&/@{-1,1},
Line[{{# a,-.15},{# a,-1.2}}]&/@{-1,1},
Line[{{.3,#b},{1.4,#b}}]&/@{-1,1},
Arrowheads[.04{-1,1}],
Arrow[{{-c,0},{.3,.67}}],
Arrow[{{.3,.67},{c,0}}],
Arrow[{{-c,-.9},{c,-.9}}],
Arrow[{{-a,-1.1},{a,-1.1}}],
Arrow[{{1.3,-b},{1.3,b}}],
Text[Style[Subscript[Style["r",Italic],1]],Mean[{{-c,0},{.3,.67}}],Background->White],
Text[Style[Subscript[Style["r",Italic],2]],Mean[{{.3,.67},{c,0}}],Background->White],
Text[Style[Subscript[Style["F",Italic],1]],{-c-.08,-.15},Background->White],
Text[Style[Subscript[Style["F",Italic],2]],{c+.1,-.15},Background->White],
Text[Style["C",Italic],{0,-.14}],
Text[Style["major axis",Italic],{0,-1.3}],
Text[Style["minor axis",Italic],{1.6,0},{0,0},{0,-1}],
Text[Style[Row[{" ",2,Style["a",Italic]," "}]],{0,-1.11},Background->White],
Text[Style[Row[{" ",2,Style["c",Italic]," "}]],{0,-.91},Background->White],
Text[Style[Row[{2,Style["b",Italic]}]],{1.3,0},Background->White]
}]]]

Initializing the Ellipse

To begin, we defined the semi-major axis (a), the semi-minor axis (b), and the length from the origin to the focus (c) in terms of perihelion and aphelion. To solve for a and c, we used the definitions of aphelion and perihelion. To solve for b, we used the definition of an ellipse: “curved line forming a closed loop, where the sum of the distances from two points (foci) to every point on the line is constant.” Using the variables from the diagram above, we set (Subscript[r, 1])=(Subscript[r, 2]) so that (Subscript[r, 1]) and (Subscript[r, 2]) were the same distances from the foci to a point on the ellipse. This implies 2(Subscript[r, 1])=2a, so (Subscript[r, 1])=a. Then using the Pythagorean Theorem, (c^2)+(b^2)=(a^2)  implies b=(Sqrt[(a^2)-(c^2)]).  We also defined a, b, and c in terms of eccentricity. We know that eccentricity = (c/a) and that c =(Sqrt[(a^2)-(b^2)]) . We can rewrite eccentricity as ((Sqrt[(a^2)-(b^2)])/a). We then solve for b which gives us b = a (Sqrt[1-(eccentricity^2)]). In the code below, we set a = 6. Using the real values for perihelion and aphelion, the semi-major axis a is 57,909,050.  Rather than dealing with these large astronomical numbers, we rounded and scaled a to be 6. The value for a is not crucial as long as the relationships between a, b, and c with the respective to eccentricity are correct.

(*   Real Values for Mercury's Orbit: 
	 perihelion=46001200;
		aphelion=69816900;
		a = .5(aphelion + perihelion);
	 c = a - perihelion;  
	 b = Sqrt[a^2 - c^2]
   *) 

a=6;
e=.205;
b=a*Sqrt[1-e^2];
c=Sqrt[a^2-b^2];

(*    The image below uses the values for a, b, and c with regard to the eccentricity and shows how those values are defined.    *)
Show[Plot[{b^2{1-{x^2/a^2}}^{1/2},-{b^2{1-{x^2/a^2}}^{1/2}}},{x,-a,a},PlotStyle->{Black,Black},Ticks->None], Graphics[{Yellow,Disk[{-c,0},{a/10,b}],Black,Line[{{0,5.9b},{c,0}}],Line[{{0,5.9b},{-c,0}}],Line[{{-a,-2},{-a/2-.3,-2}}],Line[{{0,-2},{-a/2+.3,-2}}],Text["b",{-a/15,2.5b}],Text["r = a",{a/4.5,2.5b}],Text["c",{a/10,-b/2}],Text["a",{-a/2,-2}]}]]

Using Kepler's Second Law, which states "A line joining a planet and the sun sweeps out equal areas in equal intervals of time," we were able to derive an equation that represents time in terms of area.  Area can be used as a measure of time since they are proportional to each other according to Kepler’s Second Law. The function of position that gives time is demonstrated by the equation A(ϕ)=(1/2)(c b sin(ϕ)+a b ϕ). To derive this function, it is easiest to separate the area into two parts: the area of a triangle and the area of a sector of the ellipse. The area of a trianlge is (1/2)(base)(height). Therefore the area of the triangle in this ellipse is (1/2)(c b sin(ϕ)), where c is the length of the base and b sin(ϕ) is the height. The formula for the area of a sector of an ellipse is (1/2)ϕ a b.  Then we add these two areas together to get the area traveled from the angle at a focus, and the result is  A(ϕ)=(1/2)(c b sin(ϕ)+a b ϕ).  To get the equation in terms of one Mercury year, we multiply A(ϕ) by (1/(a b π)) since the distance traveled in one year is 2 a b π. This new equation is A(ϕ)=(1/(2 a b π))(c b sin(ϕ)+a b ϕ), which is a function of the area which produces time throughout Mercury's year. In order to obtain a function of time that gives position, we need to invert this equation. The second animation uses this inverted function to show Mercury orbiting the Sun and demonstrates the increased speed of Mercury at perihelion as well as the decreased speed at aphelion.

A[ϕ_]:=1/(2*a b Pi) (c b Sin[ϕ]+ a b ϕ)
θ[time_]:=InverseFunction[A][time]

(*   The picture below expains how the area of the triangle in blue and the area of the ellipse from the central angle in purple are added together to form the area function, A[ϕ], from the angle at the focus.     *)
d=Pi/4;
Show[Plot[{b{1-{x^2/a^2}}^{1/2},-{b{1-{x^2/a^2}}^{1/2}}},{x,-a,a},PlotRange->{{-a-1,a+1},{-b-1,b+1}}, Ticks->None,PlotStyle->{Black,Black}],Graphics[{Yellow,Disk[{- c,0},{a/10,b/6}],LightBlue, Polygon[{{-c,0},{0,0},{a Cos[d],b Sin[d]}}],LightPurple,Disk[{0,0},{a,b},{0,Pi/4}],Red,PointSize[Large],Point[{a Cos[d],b Sin[d]}],Black,Text["(a cos(ϕ), (b sin(ϕ))",{a Cos[d]+.75,b Sin[d] + 1.75}]}]]

(*    The ellipse below demonstrates the motion of Mercury around the sun. It shows the acceleration as Mercury approaches the sun and the deceleration as it gets farther away from the sun. This animation also uses the inverted function θ[area] to give the position of Mercury for any given time during its orbit.      *)
Animate[ Show[Plot[{b{1-{x^2/a^2}}^{1/2},-{b{1-{x^2/a^2}}^{1/2}}},{x,-a,a},PlotRange->{{-a-1,a+1},{-b-1,b+1}},Axes->False,PlotStyle->{Black,Black}],Graphics[{Cyan,Line[{{-c,0},{a*Cos[θ[t]],b * Sin[θ[t]]}}], Yellow,Disk[{- c,0},{a/10,b/6}],PointSize[Large],Red, Point[{a*Cos[θ[t]],b * Sin[θ[t]]}]}]],{t,0.001,1,Pi/10000},DefaultDuration->8,AnimationRunning->False]

Vectors to Track Sun’s Position

Now that the position of Mercury can be tracked,  we begin to take into account Mercury’s rotation and the tracking of the sun from Mercury. To do so, we look at the angle between the vector from Mercury to the sun and the vector for Mercury’s horizon line.  The vector from Mercury to the sun is denoted by (-c-a cos(θ[t]), -b sin(θ[t])) since Mercury is at (a cos(θ[t]), b sin(θ[t])) and the sun is at (-c,0).  The image below illustracts this vector:

Show[Plot[{b^2{1-{x^2/a^2}}^{1/2},-{b^2{1-{x^2/a^2}}^{1/2}}},{x,-a-1,a+1},PlotStyle->{Black,Black},Ticks->None],Graphics[{{Red,PointSize[Large],Point[{a*Cos[Pi/4],4*b+1}]},{Yellow,Disk[{-c,0},{a/8,a}]},{Cyan,Arrow[{{a*Cos[Pi/4],4*b+1},{-c,0}}]},Black,Point[{-c,0}],Text["M2S",{a-5,b+9}],Text["(a cos(θ[t]),b sin(θ[t]))",{a Cos[Pi/4]+1.2,5*b}],Text["(-c,0)",{-c,-4}]}]]

Now suppose γis the angle of that Mercury’s horizon line has changed as it rotates. Since it takes Mercury two orbits to rotate three times, the angle to area ratio is ((2π)/(2/3))=3π. This implies that in time t Mercury will have rotated γ=3π t + (Subscript[γ, 0]), where (Subscript[γ, 0]) is the intial angle. Therefore, the vector for Mercury’s horizon line is (cos(3 π t + (Subscript[γ, 0])) , sin(3 π t + (Subscript[γ, 0])) ) . Both of the images demonstrate the angle β that is producted by the relationship between the two vectors. The light blue arrow represents the vector from Mercury to the sun, and the darker blue arrow is Mercury’s horizon line.The first image shows the vector from Mercury to the sun (M2S), and it also demonstrates Mercury’s horizon line as it spins. Notice that it takes Mercury two-thirds of its orbit to fully rotate once causing it’s horizon line to be pointing the same direction once again. The animation below shows the relationship between the two vectors and demonstrates the movement as Mercury rotates and orbits the sun.

Show[Plot[{b^2{1-{x^2/a^2}}^{1/2},-{b^2{1-{x^2/a^2}}^{1/2}}},{x,-a-1,a+1},PlotStyle->{Black,Black},Ticks->None],Graphics[{{Red,PointSize[Large],Point[{a*Cos[Pi/4],4*b+1}],Point[{a*Cos[3Pi/2]+2,b*Sin[3Pi/2]-26.6}],Point[{a*Cos[6Pi/7]-.57,b*Sin[6Pi/7]}]},{Yellow,Disk[{-c,0},{a/8,a}]},{Cyan,Arrow[{{a*Cos[Pi/4],4*b+1},{-c,0}}]},{Blue,Arrow[{{a*Cos[Pi/4],4*b+1},{a,4.25b}}],Arrow[{{a*Cos[3Pi/2]+2,b*Sin[3Pi/2]-26.6},{a-2,-5.4b-.1}}],Arrow[{{a*Cos[6Pi/7]-.57,b*Sin[6Pi/7]},{a*Cos[6Pi/7]-2,b*Sin[6Pi/7]}}]},Black,Point[{-c,0}],Text["M2S",{a-5,b+9}],Text["Horizon Line",{a*Cos[Pi/4]+.7,4.7*b}]}]]

Graphics[{PointSize[Large],Point[{0,0}],Blue,Arrow[{{0,0},{1,.25}}],Cyan,Arrow[{{0,0},{.5,1}}],Black,Text["β",{.1,.1}],Text["Horizon Line",{.7,.1}],Text["M2S",{.17,.5}]}]

Animate[ Show[Plot[{b{1-{x^2/a^2}}^{1/2},-{b{1-{x^2/a^2}}^{1/2}}},{x,-a,a},PlotRange->{{-a-3,a+3},{-b-3,b+3}},Axes->False,PlotStyle->{White,White}],Graphics[{ Yellow,Disk[{- c,0},{a/10,b/6}],Cyan,Arrow[{{a*Cos[θ[t]],b * Sin[θ[t]]},{-c,0}}],Blue, Arrow[{ {a Cos[θ[t]],b Sin[θ[t]]},{a Cos[θ[t]]+3Cos[3 Pi t],b Sin[θ[t]]+3Sin[3Pi t]}}],PointSize[Large],Red, Point[{a*Cos[θ[t]],b * Sin[θ[t]]}]}],Background->Black],{t,0.001,2,.00010000},DefaultDuration->10,AnimationRunning->False]

To find the angle between these two vectors, we use the definitions of the dot product and the cross product.
	
		 cos(β)=((NormalizedM2S · HorizonLine)/(||NormalizedM2S||  ||HorizonLine||
))
sin(β) = ((NormalizedM2S × HorizonLine)/(||NormalizedM2S|| ||HorizonLine||))
		 
Note that since both the vectors NormalizedM2S and Horizonline are unit vectors, their magnitudes are 1. The graphs for both functions are below:

(*    M2S[t] is the vector from Mercury to the Sun. To make M2S a unit vector, we divide by the length of M2S which results in NormalizedM2S[t]. HorizonLine[t] is the vector for Mercury's horizon line.  
The sine and cosine of β are initialized, and the tangent of β is obtained by dividing sin/cosine.   *)
M2S[t_]:={-c-a Cos[θ[t]],-b Sin[θ[t]]}
DistanceM2S[t_]:=Norm[M2S[t]]
NormalizedM2S[t_]:=M2S[t]/DistanceM2S[t]

InitialAngle=Pi/2;
HorizonLine[t_]:={Cos[3 Pi t+ InitialAngle], Sin[3 Pi t+InitialAngle]}
cosAngle[t_]:=NormalizedM2S[t].HorizonLine[t]
sinAngle[t_]:=Det[{NormalizedM2S[t],HorizonLine[t]}]
tanAngle[t_]:=-sinAngle[t]/-cosAngle[t]
Plot[sinAngle[t],{t,0,2}]
Plot[cosAngle[t],{t,0,2}]
Plot[tanAngle[t],{t,0,2}]

As the graphs above demonstrate, there is a unique occurrence when t=.5 and t=1.5.

Retrograde Motion of the Sun

Zooming in on the sine graph allows us to more clearly understand the phenomenon occuring. Before the Sun reaches the point of aphelion, it reverses direction and goes retrograde in the sky for a short time before continuing in its orbit around Mercury.

Plot[sinAngle[t],{t,.4,.6}]

The animation below depicts the unique phenomenon. The person below is standing on Mercury’s equator with the sun directly underneath him at initial position aphelion. Notice that when Mercury is at perihelion ( t=.5) the sun goes up, down, and then back up. This is illustrated in the sine function above. Also, when Mercury is at perihelion again, the sun goes down, up, and back down. Mercury reaches perihelion twice since Mercury’s solar day is two Mercurian years.

Animate[Graphics[{White,Point[{0,-1.5}],Point[{0,1.5}],Yellow, PointSize[Large], Point[{cosAngle[t],sinAngle[t]}],Orange,Circle[{cosAngle[t],sinAngle[t]},.25],{Green, Circle[{0,5/16},1/16],Line[{{0,1/4},{0,1/8}}],Line[{{-1/10,3/16},{1/10,3/16}}],Line[{{0,1/8},{-1/10,0}}],Line[{{0,1/8},{1/10,0}}],Black,Line[{{-2,0},{2,0}}]}}],{t,0,2},DefaultDuration->15,AnimationRunning-> False]

This phenomenon observed in both the graphs and the animation represent Mecury’s double sunrise and double sunset. This occurs because “Mercury’s angular orbital velocity exceeds its angular rotational velocity.” When Mercury is at perihelion, it is orbiting the sun faster than it is rotating around its axis.

The Size of the Sun in the Mercurian Sky

Another thing we need to understand is the perspective of the sun from Mercury. Suppose someone is standing on Mercury’s equator. As illustrated in the image below when α is larger, the sun is closer to Mercury, and therefore the sun would appear to be larger.The angle α can be defined as α =(tan^(-1))(((Radius of the Sun)/(Distance from Mercury to the Sun))) .

Show[Graphics[{Yellow, Disk[{0,10},4],Red,Disk[{0,-1},.5],Black, Line[{{0,-1},{4,10}}],Line[{{4,10},{-4,10}}],Line[{{-4,10},{0,-1}}],Line[{{0,10},{0,-1}}],Text["α",{.25,0}],Text["Sun's Radius",{2,10.25}],Text["Dist. to Sun",{-1,5}]}]]

(*Now, we are concerned with generating data with respect to the real values associated with Mercury. We reinitialize all parameters with the correct numbers*)
perihelion=46001200;
aphelion=69816900;
a = .5(aphelion + perihelion);
c = a - perihelion;  
b = Sqrt[a^2 - c^2];
A[ϕ_]:=1/(2*a b Pi) (c b Sin[ϕ]+ a b ϕ)
θ[area_]:=InverseFunction[A][area]
M2S[t_]:={-c-a Cos[θ[t]],-b Sin[θ[t]]}
DistanceM2S[t_]:=Norm[M2S[t]]
NormalizedM2S[t_]:=M2S[t]/DistanceM2S[t]
InitialAngle=Pi/2;
HorizonLine[t_]:={Cos[3 Pi t+ InitialAngle], Sin[3 Pi t+InitialAngle]}
cosAngle[t_]:=NormalizedM2S[t].HorizonLine[t]
sinAngle[t_]:=Det[{NormalizedM2S[t],HorizonLine[t]}]
tanAngle[t_]:=-sinAngle[t]/-cosAngle[t]


radSun=695500;
sunSize[t_]:=2ArcTan[radSun/DistanceM2S[t]]
sunDegrees[t_]:=sunSize[t]*360/2Pi
Plot[sunSize[t],{t,0,2}]
FindMaximum[sunSize[t],t]
FindMinimum[sunSize[t],{t,1.5}]

The change in the size of the sun is plotted above, and the maximum and minimum values can be found numerically.

Using this, a more accurate animation of the Sun rising and setting on Mercury can be created. The diameter of the Sun is adjusted as time goes by. The first perspective is from someone looking out of an “Eastern” window as the sun rises, sets, and rises again. The second perspective is someone looking out a “Western” window watching the sun set, rise, and set again. The viewing angle from the windows is 18° in all directions.

Animate[Graphics[{Red,PointSize[2sunSize[t]],Point[{0,tanAngle[t]}],Black,Line[{{Tan[Pi/10],0},{-Tan[Pi/10],0}}],Line[{{-Tan[Pi/10],-Tan[Pi/10]},{-Tan[Pi/10],Tan[Pi/10]}}],Line[{{Tan[Pi/10],-Tan[Pi/10]},{Tan[Pi/10],Tan[Pi/10]}}],Line[{{Tan[Pi/10],Tan[Pi/10]},{-Tan[Pi/10],Tan[Pi/10]}}]},PlotRange->{{-Tan[Pi/10],Tan[Pi/10]},{0,Tan[Pi/10]}}],{t,.25,.75},DefaultDuration->15,AnimationRunning->False]

Animate[Graphics[{Red,PointSize[2sunSize[t]],Point[{0,-tanAngle[t]}],Black,Line[{{Tan[Pi/10],0},{-Tan[Pi/10],0}}],Line[{{Tan[Pi/10],0},{-Tan[Pi/10],0}}],Line[{{-Tan[Pi/10],-Tan[Pi/10]},{-Tan[Pi/10],Tan[Pi/10]}}],Line[{{Tan[Pi/10],-Tan[Pi/10]},{Tan[Pi/10],Tan[Pi/10]}}],Line[{{Tan[Pi/10],Tan[Pi/10]},{-Tan[Pi/10],Tan[Pi/10]}}]},PlotRange->{{-Tan[Pi/10],Tan[Pi/10]},{0,Tan[Pi/10]}}],{t,0.25,.75},DefaultDuration->15,AnimationRunning->False]

Miscellaneous Facts

One final thing to investigate is the velocity of Mercury in its orbit around the Sun. Mercury is on average the fastest planet and its speed at perihelion is the fastest thing in our solar system.

Plot[θ'[t],{t,0,2}]
FindMaximum[θ'[t],{t,0,2}]
FindMinimum[θ'[t],{t,0,2}]

Conclusion

In conclusion, many calculations and derivations were completed to demonstrate this unique phenomenon on Mercury.  First, equations for a, b, and c in terms of perihelion and aphelion were derived, and these values were also adjusted based on eccentricity.  Kepler’s Second Law was used to represent time in terms of area, which was then inverted to obtain a function of time which gives position.  This equation was used to produce the animation which shows the sling-shot effect of Mercury’s orbit due to the increased speed at perihelion. Next, vectors were used to demonstrate the angle of the Sun’s path around Mercury. Using the angle in an animation showed that an observer on Mercury could witness a double sunrise and a double sunset, depending on his initial position. The retrograde motion of the Sun is an interesting phenomenon, and many mathematical procedures were completed to understand and demonstrate this occurrence.

Acknowledgements

We would like to thank Louisiana State University for hosting us this summer along with the Math Department and the entire VIGRE program sponsored by the National Science Foundation. We would also like to personally thank Dr. Larry Smolinsky and Richard Frnka for their contributions and guidance.

References

1.	Exploring Mercury: The Iron Planet, Robert G. Strom
2.	http://mathworld.wolfram.com/Ellipse.html
3.	http://nssdc.gsfc.nasa.gov/planetary/factsheet/mercuryfact.html
4.	http://nssdc.gsfc.nasa.gov/planetary/factsheet/sunfact.html
5.	http://www.drennon.org/science/kepler.htm
6.	http://www.youtube.com/watch?v=nPprOO2u1gk
7.	http://dictionary.reference.com/browse/ellipse
8.	http://en.wikipedia.org/wiki/Mercury_(planet)